mirror of
https://github.com/iNavFlight/inav.git
synced 2025-07-14 11:59:56 +03:00
fc0e5e2741
* Get setting default values from settings.yaml * settings: Make the generator more robust and versatile - Add support for resolving types and values in multiple compilers - Add support for resolving types and values in clang 10 - Add support for using the host compiler for resolving the settings This allows us to run the generator for the unit tests, since they now need the settings_generated.h file to get the default setting values from it. * Fix regexps in settings.rb and add execution bit * Fix git revision issue * Fix issue with settings validation * Fix issue with targets not defining USE_MAG Co-authored-by: Alberto García Hierro <alberto@garciahierro.com>
41 lines
1.4 KiB
CMake
41 lines
1.4 KiB
CMake
set(SETTINGS_GENERATED "settings_generated")
|
|
set(SETTINGS_GENERATED_C "${SETTINGS_GENERATED}.c")
|
|
set(SETTINGS_GENERATED_H "${SETTINGS_GENERATED}.h")
|
|
set(SETTINGS_FILE "${MAIN_SRC_DIR}/fc/settings.yaml")
|
|
set(SETTINGS_GENERATOR "${MAIN_UTILS_DIR}/settings.rb")
|
|
|
|
include(CMakeParseArguments)
|
|
|
|
function(enable_settings exe name)
|
|
get_generated_files_dir(dir ${name})
|
|
get_target_property(options ${exe} COMPILE_OPTIONS)
|
|
get_target_property(includes ${exe} INCLUDE_DIRECTORIES)
|
|
list(TRANSFORM includes PREPEND "-I")
|
|
get_target_property(defs ${exe} COMPILE_DEFINITIONS)
|
|
list(TRANSFORM defs PREPEND "-D")
|
|
list(APPEND cflags ${options})
|
|
list(APPEND cflags ${includes})
|
|
list(APPEND cflags ${defs})
|
|
|
|
cmake_parse_arguments(
|
|
args
|
|
# Boolean arguments
|
|
""
|
|
# Single value arguments
|
|
"OUTPUTS;SETTINGS_CXX"
|
|
# Multi-value arguments
|
|
""
|
|
# Start parsing after the known arguments
|
|
${ARGN}
|
|
)
|
|
|
|
set(output ${dir}/${SETTINGS_GENERATED_H} ${dir}/${SETTINGS_GENERATED_C})
|
|
add_custom_command(
|
|
OUTPUT ${output}
|
|
COMMAND
|
|
${CMAKE_COMMAND} -E env CFLAGS="${cflags}" TARGET=${name} PATH=$ENV{PATH} SETTINGS_CXX=${args_SETTINGS_CXX}
|
|
${RUBY_EXECUTABLE} ${SETTINGS_GENERATOR} ${MAIN_DIR} ${SETTINGS_FILE} -o "${dir}"
|
|
DEPENDS ${SETTINGS_GENERATOR} ${SETTINGS_FILE}
|
|
)
|
|
set(${args_OUTPUTS} ${output} PARENT_SCOPE)
|
|
endfunction()
|