mirror of
https://git.libcamera.org/libcamera/libcamera.git
synced 2025-07-14 16:09:51 +03:00
b7d48634c5
Support easier usage of the v4l2 compatibility layer with a script that handles the LD_PRELOAD for applications. The wrapper can be prefixed to launch any application with the preload set: $ libcamera-v4l2 v4l2-ctl --list-devices \_SB_.PCI0.GP13.XHC0.RHUB.PRT4- (libcamera:0): /dev/video0 platform/vimc.0 Sensor B (libcamera:1): /dev/video2 /dev/video3 /dev/video4 Specifying '-d' once before the command to run will enable V4L2Compat layer debug output from libcamera. Specifying '-d' twice will enable all debug levels from all libcamera components and provide a very detailed log for analysis. Signed-off-by: Kieran Bingham <kieran.bingham@ideasonboard.com> Reviewed-by: Laurent Pinchart <laurent.pinchart@ideasonboard.com> Reviewed-by: Paul Elder <paul.elder@ideasonboard.com>
46 lines
1.5 KiB
Meson
46 lines
1.5 KiB
Meson
# SPDX-License-Identifier: CC0-1.0
|
|
|
|
if not get_option('v4l2')
|
|
v4l2_enabled = false
|
|
subdir_done()
|
|
endif
|
|
|
|
v4l2_enabled = true
|
|
|
|
v4l2_compat_sources = files([
|
|
'v4l2_camera.cpp',
|
|
'v4l2_camera_file.cpp',
|
|
'v4l2_camera_proxy.cpp',
|
|
'v4l2_compat.cpp',
|
|
'v4l2_compat_manager.cpp',
|
|
])
|
|
|
|
v4l2_compat_cpp_args = [
|
|
# Meson enables large file support unconditionally, which redirect file
|
|
# operations to 64-bit versions. This results in some symbols being
|
|
# renamed, for instance open() being renamed to open64(). As the V4L2
|
|
# adaptation wrapper needs to provide both 32-bit and 64-bit versions of
|
|
# file operations, disable transparent large file support.
|
|
'-U_FILE_OFFSET_BITS',
|
|
'-D_FILE_OFFSET_BITS=32',
|
|
'-D_LARGEFILE64_SOURCE',
|
|
'-fvisibility=hidden',
|
|
]
|
|
|
|
v4l2_compat = shared_library('v4l2-compat',
|
|
v4l2_compat_sources,
|
|
name_prefix : '',
|
|
install : true,
|
|
dependencies : [libcamera_private, libdl],
|
|
cpp_args : v4l2_compat_cpp_args)
|
|
|
|
# Provide a wrapper script to support easily loading applications with the V4L2
|
|
# adaptation layer.
|
|
|
|
cdata = configuration_data()
|
|
cdata.set('LIBCAMERA_V4L2_SO', get_option('prefix') / get_option('libdir') / 'v4l2-compat.so')
|
|
|
|
configure_file(input : 'libcamerify.in',
|
|
output : 'libcamerify',
|
|
configuration : cdata,
|
|
install_dir : get_option('bindir'))
|